@Echo off

rem Script zum hinzufügen der RefileUser in die Gruppen und die RolleUpdate
rem erstellt am 08.11.2007 21:26:50 J.Fes
rem Hinweis alle mit ## Gitter gekennzeichneten Stellen sind anzupassen


Echo TcEng Prompt durchlaufen ..
rem ## aufruf Tceprompt
call D:\ugenv\start_apps\windows\start_nx4.bat de tceng_prompt tceng 913
Echo TcEng Prompt durchlaufen .. OK


set PrgRoot_LP=%~dp0
set PrgRoot_LP=%PrgRoot_LP:~0,-1%

set path=%PrgRoot_LP%;%BinRoot_LP%;%Path%

call :DateTimeNowGet


Echo Export der Organisations Daten !!
call :plmxml_export Person
call :plmxml_export User
call :plmxml_export Role
call :plmxml_export Group
call :plmxml_export GroupMember
pause

Echo EInfuegen der User in die Gruppen und Rollen
rem ## hier sind soviele Zeilen wie es RefileUsergibt zu erstellen und anzupassen
call :AddUserToAllGroupsInRoleUpdate refile_user
call :AddUserToAllGroupsInRoleUpdate refile_user01
rem call :AddUserToAllGroupsInRoleUpdate refile_user02


goto :ende

:AddUserToAllGroupsInRoleUpdate


 set UserCurr=%1
 Echo Edit User: %UserCurr% --------------

 rem ## RoleName überprüfen !
 set RoleName=Update
 rem ## hier muss die Liste der Gruppen angepasst werden !
 rem ## WICHTIG: bitte darauf Achten das nur die existierende GruppenNamen in der Liste stehen
 rem ##          da sonst die Gruppe vom make_user Tool erzeugt wird.
 set GroupList=Gruppe1;Gruppe2;Gruppe3
 for /d %%i in (%GroupList%) do call :TceEditUser %UserCurr% %%i %RoleName%
 goto :eof

:TceEditUser
 rem Editiert die Gruppen und Rollen zugehörigkeit eines Users
 rem Hinweis: Existiert die erforderliche Gruppe oder Rolle nicht so werden diese Automatisch erzeugt
 rem          Ist die Rolle der Gruppe noch nicht hinzugefügt worden so wird diese Automatisch der Gruppe hinzugefügt

 set UserCurr=%1
 set GroupCurr=%2
 set RoleName=%3
 Echo Update user property of:%UserCurr% group:%GroupCurr% role:%RoleName%
 rem set toRun=Make_user -u=infodba -p=infodba -g=dba -update -user=%UserCurr% -group=%GroupCurr% -role=%RoleName%
 set toRun=Make_user -u=infodba -p=infodba -g=dba -user=%UserCurr% -group=%GroupCurr% -role=%RoleName% -Person=%UserCurr%
 Echo %toRun%
 call %toRun%
 goto :eof


 rem --------------------------------------------------
:plmxml_export

 set ClassName=%1
 set plmXml_DPNE=%PrgRoot_LP%\PlmXML_%DateTimeNowFileExt%_%ClassName%.xml
 Echo Exportiere: %ClassName%
 Echo    in File: %plmXml_DPNE%
 plmxml_export -u=infodba -p=infodba -g=dba -xml_file=%plmXml_DPNE% -class=%ClassName%

 goto :eof

rem --------------------------------------------------------------------
:DateTimeNowGet
 rem call :DateTimeNowGet
 rem Set File_LPNE=%DatRoot_LP%\MyName-%DateTimeNowFileExt%.txt


 if     "%time:~0,1%"==" " set time-h=0%time:~1,1%
 if not "%time:~0,1%"==" " set time-h=%time:~0,2%

 if     "%time:~3,1%"==" " set time-m=0%time:~4,1%
 if not "%time:~3,1%"==" " set time-m=%time:~3,2%

 set Date-Y=%Date:~6,4%
 set Date-M=%Date:~3,2%
 set Date-D=%Date:~0,2%
 set DateTimeNowFileExt=%Date-Y%-%Date-M%-%Date-D%-%time-h%-%time-m%
 goto :eof


:ende
 Pause