 setlocal
  rem J.Fes 02.06.2011 func: Checks Files Version
  rem -- Rootpfade setzen -------------------------------------------------------
  set CmdCurRoot_DP=%~dp0
  set CmdCurRoot_DP=%CmdCurRoot_DP:~0,-1%
  set path=%CmdCurRoot_DP%;%path%
  rem Example: call LibCheck libnxmgr_im.dll "2007.1.8.43080" "05-13-2010" "2,654,208"  libnxmgr_im_DPNE libnxmgr_im_dll_CRes libnxmgr_im_dll_Msg
  set File_DN=%~1
  set FileVer_desired=%~2
  set FileDate_desired=%~3
  set FileSize_desired=%~4

  call fileFindInPath_GetVerInfo.cmd "%File_DN%" FileFound_DPNE FileInfo FileVer FileDate FileSize

  if /I "%JobMgr_Debug%"=="ON" (
   echo ##Debug: LibCheck Info:
   echo FileFound_DPNE:%FileFound_DPNE%
   echo FileInfo      :%FileInfo%
   Echo FileVer       :%FileVer%
   Echo FileDate      :%FileDate%
   Echo FileSize      :%FileSize%
  )

  set FileCheckResult=Err
  rem wenn kein vorgabe wert angegeben wurde dann diesen auf leer stellen
  if /i "%FileVer_desired%"  equ "" set FileVer=
  if /i "%FileDate_desired%" equ "" set FileDate=
  if /i "%FileSize_desired%" equ "" set FileSize=

  if /i "%FileVer_desired%" equ "%FileVer%"  if /i "%FileDate_desired%" equ "%FileDate%" if /i "%FileSize_desired%" equ "%FileSize%" set FileCheckResult=OK
  if /i "%FileVer_desired%" equ "%FileVer%"   set ResMsg=V:[OK:%FileVer%]
  if /i "%FileVer_desired%" neq "%FileVer%"   set ResMsg=V:[Err:%FileVer_desired% NEQ %FileVer%]
  if /i "%FileDate_desired%" equ "%FileDate%" set ResMsg=%ResMsg% D:[OK:%FileDate%]
  if /i "%FileDate_desired%" neq "%FileDate%" set ResMsg=%ResMsg% D:[Err:%FileDate_desired% NEQ %FileDate%]
  if /i "%FileSize_desired%" equ "%FileSize%" set ResMsg=%ResMsg% S:[OK:%FileSize%]
  if /i "%FileSize_desired%" neq "%FileSize%" set ResMsg=%ResMsg% S:[Err:%FileSize_desired% NEQ %FileSize%]
 endlocal& set %5=%FileFound_DPNE%& set %6=%FileCheckResult%& if "%7" neq "" set %7=%ResMsg%
